Install Vanced

Instalare ReVanced

In primul rand trebuie dezinstalate versiunile vechi de microg, music, revanced. Clear cache, clear data si uninstall la fiecare, nu doar uninstall!!!. Obligatoriu trebuie ras TOT!
Numai daca ati incercat tot ce este explicat mai jos si nu merge sub nicio forma, reveniti la pasul asta si dati reboot in recovery si wipe cache partition. (extrem de rar a fost necesar)

Revanced nu mai e ce trebuie, voi explica mai jos cum se procedeaza cu Morphe, proiect desprins din Revanced, mult mai clar si la obiect.

Site oficial aici.

Softuri necesare:
- MicroGRE aici
- Morphge Manager aici Instalati Morphe Manager si aveti linkuri pt a downloada variantele patch-uibile, va deschide direct. Informativ aveti aici cam care sunt versiunile de Youtube si YouTube-Music. Astea sunt gata patch-uite dar am avut suprize, e posibil sa faca figuri.
Dupa ce patch-uiti si apoi instalati YT si YTMusic, deschideti YTMusic si va logati. By default va pune niste icoane specifice care se pot schimba.
Iata setarile in YT (dupa instalare), similar sunt si in YTMusic:
--Settings/M Settings/General/App incon - Original.
--Settings/M Settings/Swipe controls si aici aveti Left/Right/Top unde setati Brightness/Volume/Speed care unde considerati potrivit.
--Settings/M Settings/Miscellaneous/Show MicroG battery optimization dialog - disabled.
--Settings/Time management/Remind me when it's bedtime + Remind me to take a break - ambele disabled.
Am ajuns la concluzia ca merita sa lasi Managerul instalat pt ca la un YT update tine minte toate setarile.

Am descoperit https://github.com/Graywizard888/Enhancify care usureaza munca f mult. Aplicatia inlocuieste managerul.
Instalati termux tot de pe github pt ca din google play nu functioneaza, nu am inteles de ce. Deci instalati -v8a.apk Il rulati si in el dati paste la urmatoarea comanda, din documentatia Enhancify:
termux-setup-storage && git clone https://github.com/Graywizard888/Enhancify.git && cd Enhancify && bash install.sh
Asteptati sa isi traga tot ce are nevoie dupa care enhancify Enter si apare meniul. 1 Patch app de unde alegeti YouTube-Music [RECOMMENDED],
va downloadeaza apk si apoi ii face patch plus install.
Similar pt YouTube, exact aceeasi pasi. Ca o mentiune, aceasta aplicatie are posibilitatea sa schimbi sursele, e o lista care incepe cu Revanced si printre altele are si Morphe.
Fata de revancify, aplicatia din care s-a facut fork, enhancify asta va instaleaza si GsmCore daca nu il aveti, varianta in functie de sursa.

------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
O mica mentiune, nu merge download, daca va intereseaza sa downloadati vreun video in telefon pt continut offline, recomand NewPipe de aici.
Newpipe este o solutie buna dar nu va puteti loga, nu are suport pt treaba asta.
Pe pc cu windows daca vreti sa downloadati ceva de pe youtube exista yt-dlp
Iata un script actualizat care va downloadeaza toate softurile necesare si implica un singur download manual (daca deno va da fail)

@echo off
setlocal EnableExtensions EnableDelayedExpansion
chcp 65001 >nul
cls

set "YT_DLP_URL=https://github.com/yt-dlp/yt-dlp-nightly-builds/releases/latest/download/yt-dlp.exe"
set "FFMPEG_URL=https://github.com/yt-dlp/FFmpeg-Builds/releases/download/latest/ffmpeg-master-latest-win64-gpl.zip"
set "YTDLP_API=https://api.github.com/repos/yt-dlp/yt-dlp-nightly-builds/releases/latest"

echo.
echo =============================================
echo    YT-DLP VIDEO DOWNLOADER
echo =============================================
echo.

set "local_version="
set "remote_version="

if exist "yt-dlp.exe" (
    echo [1/5] Verific versiunea locala yt-dlp...
    for /f "delims=" %%V in ('yt-dlp.exe --version 2^>nul') do set "local_version=%%V"
    echo     Local: !local_version!
) else (
    echo [1/5] yt-dlp.exe nu exista local.
)

echo.
echo [2/5] Verific ultima versiune online...
for /f "usebackq delims=" %%A in (`powershell -NoProfile -Command "(Invoke-RestMethod '!YTDLP_API!').tag_name"`) do set "remote_version=%%A"

if not defined remote_version (
    echo     ERROR: Nu s-a putut obtine versiunea online.
    if not exist "yt-dlp.exe" (
        echo     CRITICAL: Lipseste yt-dlp.exe, nu pot continua.
        pause
        exit /b 1
    )
) else (
    echo     Latest: !remote_version!
    if defined local_version if /i "!local_version!"=="!remote_version!" (
        echo     yt-dlp este deja actualizat.
        goto :ffmpeg_check
    )

    echo     Actualizez yt-dlp...
    curl.exe -L "%YT_DLP_URL%" -o "yt-dlp_new.exe" --fail --silent --show-error
    if errorlevel 1 (
        echo     ERROR: Download yt-dlp a esuat.
        goto :ffmpeg_check
    )

    yt-dlp_new.exe --version >nul 2>&1
    if errorlevel 1 (
        echo     ERROR: Fisierul yt-dlp descarcat pare corupt.
        del /f /q "yt-dlp_new.exe" 2>nul
        goto :ffmpeg_check
    )

    if exist "yt-dlp.exe" del /f /q "yt-dlp.exe" 2>nul
    ren "yt-dlp_new.exe" "yt-dlp.exe"
    powershell -NoProfile -Command "Unblock-File -Path 'yt-dlp.exe'" 2>nul
    echo     yt-dlp actualizat cu succes.
)

:ffmpeg_check
echo.
echo [3/5] Verific ffmpeg...

if exist "ffmpeg.exe" (
    if exist "ffprobe.exe" (
        echo     ffmpeg este deja pregatit.
        goto :deno_check
    )
)

echo     Descarc ffmpeg...
curl.exe -L "%FFMPEG_URL%" -o "ffmpeg.zip" --fail --silent --show-error
if errorlevel 1 (
    echo     ERROR: Download ffmpeg.zip a esuat.
    goto :deno_check
)

if not exist "ffmpeg.zip" (
    echo     ERROR: ffmpeg.zip nu exista dupa download.
    goto :deno_check
)

echo     Extrag arhiva ffmpeg...
powershell -NoProfile -Command "Expand-Archive -LiteralPath 'ffmpeg.zip' -DestinationPath '.' -Force" >nul 2>&1

set "ffmpeg_found=0"
set "ffmpeg_dir="

for /d %%D in ("ffmpeg-*") do (
    if exist "%%D\bin\ffmpeg.exe" (
        copy /y "%%D\bin\ffmpeg.exe" "." >nul
        if exist "%%D\bin\ffprobe.exe" copy /y "%%D\bin\ffprobe.exe" "." >nul
        set "ffmpeg_found=1"
        set "ffmpeg_dir=%%D"
    )
)

if "!ffmpeg_found!"=="1" (
    echo     ffmpeg instalat cu succes.
    if defined ffmpeg_dir rd /s /q "!ffmpeg_dir!" 2>nul
) else (
    echo     ERROR: ffmpeg.exe nu a fost gasit in arhiva.
)

del /f /q "ffmpeg.zip" 2>nul
goto :deno_check

:deno_check
echo.
echo [4/5] Verific Deno...
set "js_arg="
set "deno_path="
set "is_admin=0"

REM === Verific daca ruleaza ca Administrator ===
net session >nul 2>&1
if not errorlevel 1 set "is_admin=1"

REM === 1. Cauta local ===
if exist "deno.exe" (
    set "deno_path=%cd%\deno.exe"
)

REM === 2. Cauta in PATH daca nu exista local ===
if not defined deno_path (
    for %%X in (deno.exe) do set "deno_path=%%~$PATH:X"
)

REM === 3. Cauta in locatia standard a installerului Deno ===
if not defined deno_path (
    if exist "%USERPROFILE%\.deno\bin\deno.exe" (
        set "deno_path=%USERPROFILE%\.deno\bin\deno.exe"
    )
)

REM === 4. Daca exista deja, foloseste-l ===
if defined deno_path (
    echo     Deno gasit: !deno_path!
    set "js_arg=--js-runtimes deno:!deno_path!"
    goto :after_deno_check
)

echo     Deno nu a fost gasit local sau in PATH.
echo     Incerc instalarea automata pentru userul curent...

if "!is_admin!"=="0" (
    echo     INFO: Scriptul NU ruleaza ca Administrator.
    echo     INFO: Asta este in regula pentru instalarea in profilul userului curent.
)

powershell -NoProfile -ExecutionPolicy Bypass -Command "try { irm https://deno.land/install.ps1 | iex } catch { exit 1 }"
if errorlevel 1 (
    echo.
    echo     ERROR: Instalarea automata Deno a esuat.
    if "!is_admin!"=="0" (
        echo     Incearca din nou manual in PowerShell:
        echo     irm https://deno.land/install.ps1 ^| iex
        echo     Sau ruleaza acest script ca Administrator si reincearca.
    ) else (
        echo     Incearca manual in PowerShell:
        echo     irm https://deno.land/install.ps1 ^| iex
    )
    goto :after_deno_check
)

REM === 5. Reverificare dupa instalare ===
set "deno_path="

if exist "deno.exe" (
    set "deno_path=%cd%\deno.exe"
)

if not defined deno_path (
    for %%X in (deno.exe) do set "deno_path=%%~$PATH:X"
)

if not defined deno_path (
    if exist "%USERPROFILE%\.deno\bin\deno.exe" (
        set "deno_path=%USERPROFILE%\.deno\bin\deno.exe"
    )
)

if defined deno_path (
    echo     Deno instalat cu succes: !deno_path!
    set "js_arg=--js-runtimes deno:!deno_path!"
) else (
    echo     WARNING: Instalarea s-a terminat, dar deno.exe nu a fost gasit imediat.
    echo     Inchide si redeschide terminalul, apoi ruleaza scriptul din nou.
    echo     Verifica si manual:
    echo     %USERPROFILE%\.deno\bin\deno.exe
)

:after_deno_check

echo.
echo [5/5] Download video
echo.

:ask_id
set "video_id="
set /p "video_id=Enter YouTube ID sau URL complet: "
if not defined video_id goto :ask_id

set "video_url=!video_id!"
echo !video_id! | findstr /i "youtube.com youtu.be" >nul
if errorlevel 1 set "video_url=https://www.youtube.com/watch?v=!video_id!"

echo.
echo Verific formatele disponibile...

if exist "cookies.txt" (
    yt-dlp.exe !js_arg! --no-playlist --cookies "cookies.txt" -F "!video_url!" > formats.tmp 2>&1
) else (
    yt-dlp.exe !js_arg! --no-playlist -F "!video_url!" > formats.tmp 2>&1
)

if not exist "formats.tmp" (
    echo ERROR: Nu s-a putut genera lista de formate.
    pause
    goto :ask_id
)

set "has_4k=0"
set "has_1080=0"
findstr /i "2160p" formats.tmp >nul 2>&1 && set "has_4k=1"
findstr /i "1080p" formats.tmp >nul 2>&1 && set "has_1080=1"

echo.
echo =============================================
echo Alege calitatea:
if "!has_4k!"=="1" echo   4k   = 4K / 2160p sau mai bun
if "!has_1080!"=="1" echo   1080 = 1080p maxim
echo   best = cea mai buna varianta disponibila
echo =============================================
echo.

set "choice="
set /p "choice=Calitate (4k/1080/best): "
set "valid=0"
set "fmt="

if /i "!choice!"=="4k" (
    if "!has_4k!"=="1" (
        set "valid=1"
        set "fmt=bestvideo[height>=2160]+bestaudio/best[height>=2160]/best"
    ) else (
        echo EROARE: 4K nu este disponibil pentru acest video.
        timeout /t 2 >nul
        goto :ask_id
    )
)

if /i "!choice!"=="1080" (
    if "!has_1080!"=="1" (
        set "valid=1"
        set "fmt=bestvideo[height<=1080]+bestaudio/best[height<=1080]/best"
    ) else (
        echo EROARE: 1080p nu este disponibil pentru acest video.
        timeout /t 2 >nul
        goto :ask_id
    )
)

if /i "!choice!"=="best" (
    set "valid=1"
    set "fmt=bestvideo+bestaudio/best"
)

if "!valid!"=="0" (
    echo EROARE: Optiune invalida.
    timeout /t 2 >nul
    goto :ask_id
)

echo.
echo Descarc video...

if exist "cookies.txt" (
    yt-dlp.exe !js_arg! --no-playlist --cookies "cookies.txt" -f "!fmt!" --merge-output-format mkv -o "%%(title)s [%%(id)s].mkv" "!video_url!"
) else (
    yt-dlp.exe !js_arg! --no-playlist -f "!fmt!" --merge-output-format mkv -o "%%(title)s [%%(id)s].mkv" "!video_url!"
)

echo.
del /f /q "formats.tmp" 2>nul
echo =============================================
echo Gata.
echo =============================================
echo.
pause
goto :ask_id

Obtineti 2 fisiere separate pe care le muxeaza singur in mkv dupa care sterge si ramaneti doar cu mkv-ul.
Este din ce in ce mai greu de pacalit google, scriptul downloadeaza ultima versiune nightly, de la zi la zi apar modificari!

Succes!

Last update 8 Aug 2026.

Instalare ReVanced

Alternativa Revanced (orphe)

Instalare automatizata

Succes!